***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 18, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84C3V9-AU A K 
.param
+vc0 = 1.046e-8		vc1 = 1.016e-8		vc2 = 1.000		vc3 = 8.036e-9		vc4 = 9.391
+tc1 = 8.051e-3		tc2 = 5.721e-3		tc3 = 4.101e-3		tc4 = 2.321e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 3.230e-15	   n = 1.079		  rs = 4.661e-1
+ibv = 1e-3		 nbv = 6.5		  bv = 3.905
+ikf = 1.118e-1
***** capacitance parameter *****
+cjo = 1.644e-10	   m = 3.692e-1		  vj = 8.140e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.117		 xti = 3
+trs1 = 8.085e-4	trs2 = 8.005e-6		tikf = 5e-3
+tbv1 = -5.938e-4	tbv2 = 1.061e-8	
.ends BZX84C3V9-AU
*$
